Как экспортировать и импортировать все запланированные задания (task sheduler) из Windows 2008 r2

Задача есть сервер windows 2008 r2 на котором есть запланированные задачи около 500 шт. нужно перенести на windows 2016 .

1. Создайте файл schtasks_tool.bat и скопируйте его на корневой локальный диск на сервере, с которого вы хотите экспортировать запланированные задачи.

2. Измените runas на свою учетную запись администратора и пароль.

3. В командной строке запустите c:\schtasks_tool.bat export.

а. Это создаст папку  c:\tasks и a c:\tnlist.txt

4. Скопируйте c:\schtasks_tool.bat, c:\tasks и c:\tnlist.txt в корневой том на сервере, на который вы хотите добавить задачи.

5. Войдите на новый сервер, перейдите в командную строку и запустите c:\schtasks_tool.bat import.

6. Отключите задачи на новом сервере (при необходимости)

rem @echo off
cls
setlocal EnableDelayedExpansion

set runasUsername=domain\administrator
set runasPassword=password

if %1. == export. call :export
if %1. == import. call :import
exit /b 0

:export
md tasks 2>nul

schtasks /query /fo csv | findstr /V /c:"TaskName" > tnlist.txt

for /F "delims=," %%T in (tnlist.txt) do (
set tn=%%T
set fn=!tn:\=#!
echo !tn!
schtasks /query /xml /TN !tn! > tasks\!fn!.xml
)

rem Windows 2008 tasks which should not be imported.
del tasks\#Microsoft*.xml
exit /b 0

:import
for %%f in (tasks\*.xml) do (
call :importfile "%%f"
)
exit /b 0

:importfile
set filename=%1

rem replace out the # symbol and .xml to derived the task name
set taskname=%filename:#=%
set taskname=%taskname:tasks\=%
set taskname=%taskname:.xml=%

schtasks /create /ru %runasUsername% /rp %runasPassword% /tn %taskname% /xml %filename%
echo.
echo.

 

Similar Posts: